Tri-Planar Terrain Shader

on

How The Tri-Planar Terrain Shader Looks Like

tri-planar terrain shader
Tri-Planar Terrain Shader
Apart from the manually drawn tile footpath the cliff walls and grass has been generated through a tri-planar shader.

How The Tri-Planar Terrain Shader Works

The shader that we make will work with the existing terrain system and no need for any custom scripts.
The first two textures provided in the terrain settings will be used to texture the terrain :
errain texture settings
Terrain Texture Settings
*Notes:-
  • First Texture Index:- Texture that appears on cliff sides.
  • Second Texture Index:- Texture that appears on flat surfaces.
  • Any subsequent textures can be used to draw on top of this as usual.
  • Drawing with either first or second texture slot acts as a eraser removing subsequent textures
The shader we will make will be working on top the existing terrain shader that Unity provides us. 
So that will require accessing the Unity shader repository for your specific version of Unity.
The version of Unity I used to create the shader is version 2017.4.
Most likely there won't be much of a difference in terms of shader code we end up writing irrespective of the Unity version.
You can download your specific version of Unity built-in shaders here: Unity Download Archive
If you just want the diffuse terrain shader : Diffuse Terrain Shader ( Unity 2017.4 version )
We will make changes to this shader to add the required functionality.
Now onto actually writing the shader.
*Comments have been provided to explain the surface shader being modified.

Shader

Shader "BitshiftProgrammer/TriPlanarTerrain"
{
    Properties {
        _TransitionFalloff ("Transition Falloff", Range(0.01, 10.0)) = 4.0
        [HideInInspector] _Control ("Control (RGBA)", 2D) = "red" {}
        [HideInInspector] _Splat3 ("Layer 3 (A)", 2D) = "white" {}
        [HideInInspector] _Splat2 ("Layer 2 (B)", 2D) = "white" {}
        [HideInInspector] _Splat1 ("Layer 1 (G)", 2D) = "white" {}
        [HideInInspector] _Splat0 ("Layer 0 (R)", 2D) = "white" {}
        [HideInInspector] _Normal3 ("Normal 3 (A)", 2D) = "bump" {}
        [HideInInspector] _Normal2 ("Normal 2 (B)", 2D) = "bump" {}
        [HideInInspector] _Normal1 ("Normal 1 (G)", 2D) = "bump" {}
        [HideInInspector] _Normal0 ("Normal 0 (R)", 2D) = "bump" {}
        // used in fallback on old cards & base map
        [HideInInspector] _MainTex ("BaseMap (RGB)", 2D) = "white" {}
        [HideInInspector] _Color ("Main Color", Color) = (1,1,1,1)
    }

    CGINCLUDE
        #pragma surface surf Lambert vertex:SplatmapVert finalcolor:SplatmapFinalColor finalprepass:SplatmapFinalPrepass finalgbuffer:SplatmapFinalGBuffer noinstancing
        #pragma multi_compile_fog
        #include "TerrainSplatmapCommon.cginc"

        float _TransitionFalloff;

        void surf(Input IN, inout SurfaceOutput o)
        {
            half4 splat_control; // Determines where each of the textures show up and by how much
            half weight; // A bit complicated thing, But it supports more than 4 textures to be used on the terrain by providing o.Alpha with weight value.
            fixed4 mixedDiffuse; //Will be the color output after putting on all the splat maps
            SplatmapMix(IN, splat_control, weight, mixedDiffuse, o.Normal); //The actual function that puts the splat map texture on the terrain, Outputs color value into mixedDiffuse.

            fixed3 col1 = tex2D(_Splat0, IN.uv_Splat0); // Takes color from from first texture applied on Terrain
            fixed3 col2 = tex2D(_Splat1, IN.uv_Splat1); // Takes color from from second texture applied on Terrain
            float upwardNormalStr = dot(half3(0, 1, 0), o.Normal) * 0.5 + 0.5; // How much the normal at that point faces upwards. Changed from -1.0 to +1.0 range to 0.0 to +1.0
            upwardNormalStr = pow(upwardNormalStr, _TransitionFalloff); // Larger _TransitionFalloff makes a sharper transition
            fixed4 triPlanarColor = fixed4(lerp(col1, col2, upwardNormalStr), 1.0); // Chooses the appropriate color based on the normal
            /*splat_control is used to determine which texture goes where.
             The Red & Green channel strength determines where & how much the _Splat0 & _Splat1 textures show up.
             Since we are manually overriding the placement of the first two textures we have to perform some check*/
            float extentOfRedAndGreen = dot(half2(1,1), splat_control.rg) * 0.5 + 0.5; // 0 :- Means no Red or Green, 1:- Means alot of Red or Green
            extentOfRedAndGreen = pow(extentOfRedAndGreen, 4); // Making the value sharper to prevent artifacts
            o.Albedo = lerp(mixedDiffuse, triPlanarColor, extentOfRedAndGreen);
            o.Alpha = weight; // To support more than 4 textures, Does not actually affect transparency. Not sure exactly how though.
        }
    ENDCG

    Category 
    {
        Tags 
        {
            "Queue" = "Geometry-99"
            "RenderType" = "Opaque"
        }
        // TODO: Seems like "#pragma target 3.0 _TERRAIN_NORMAL_MAP" can't fallback correctly on less capable devices?
        // Use two sub-shaders to simulate different features for different targets and still fallback correctly.
        SubShader { // for sm3.0+ targets
            CGPROGRAM
                #pragma target 3.0
                #pragma multi_compile __ _TERRAIN_NORMAL_MAP
            ENDCG
        }
        SubShader { // for sm2.0 targets
            CGPROGRAM
            ENDCG
        }
    }

    Dependency "AddPassShader" = "Hidden/TerrainEngine/Splatmap/Diffuse-AddPass"
    Dependency "BaseMapShader" = "Diffuse"
    Dependency "Details0"      = "Hidden/TerrainEngine/Details/Vertexlit"
    Dependency "Details1"      = "Hidden/TerrainEngine/Details/WavingDoublePass"
    Dependency "Details2"      = "Hidden/TerrainEngine/Details/BillboardWavingDoublePass"
    Dependency "Tree0"         = "Hidden/TerrainEngine/BillboardTree"

    Fallback "Diffuse"
}
Then create a material with that shader and then goto the settings tab of the terrain and set the material type to 'Custom' and put in our custom terrain shader.
That's it! Hope you learned something.
Support Bitshift Programmer by leaving a like on Bitshift Programmer Facebook Page and be updated as soon as there is a new blog post.
If you have any questions that you might have about shaders or unity development in general, don't be shy and leave a message on my facebook page or down in the comments.
For the entire source code, go HERE.
For more Shader development tutorials, go: HERE
For Unity development tutorials, go: HERE