The Unity shader documentation regarding reflection probes is pretty minimal and not at all comprehensive.
This short tutorial is intended to bring reflection probe functionalities to the forefront your future shader writing endeavors which is a fancy way of saying "Look at this cool stuff and go and use it somewhere" 😏
Here we will try just the bare minimum of making a shader that reflects the cube-map data from reflection probe and displays it on the object.
These reflection probes are basically objects that store a complete image of the environment surrounding it into a cube map which then can be read by shaders to create various effects.
More information on how reflection probes work in Unity can be found here: Using Reflection Probes In Unity
I am not going over how to set up Reflection Probes here only how to access them inside our custom shaders.
So this is what we will be making:
The reflection probe takes in the cube-map only if it is within it's range otherwise it will use the default skybox cube- map.
You might have also noticed that I'm also able to change the sharpness of the image and make it more or less blurred, This is basically what roughness does in the Unity standard shader.
We will utilize a cool capability of the cube-map which allows us to do the roughness effect as well.
As usual, we will take each section of our shader and explain it.
First, we will look at the properties:
Properties
{
_Roughness("Roughness", Range(0.0, 10.0)) = 0.0
}Let's look at our definitions within the CG PROGRAM
float _Roughness;
struct appdata
{
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f
{
float3 worldPos : TEXCOORD0;
float3 worldNormal : TEXCOORD1;
float4 pos : SV_POSITION;
};Now the vertex shader:
v2f vert (appdata v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
o.worldNormal = UnityObjectToWorldNormal(v.normal); // From local space normals to world-space normals
return o;
}Nothing complicated happened in the vertex shader.
Now the fragment shader:
fixed4 frag (v2f i) : SV_Target
{
half3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos)); //Direction of ray from the camera towards the object surface
half3 reflection = reflect(-worldViewDir, i.worldNormal); // Direction of ray after hitting the surface of object
/*If Roughness feature is not needed : UNITY_SAMPLE_TEXCUBE(unity_SpecCube0, reflection) can be used instead.
It chooses the correct LOD value based on camera distance*/
half4 skyData = UNITY_SAMPLE_TEXCUBE_LOD(unity_SpecCube0, reflection, _Roughness); //UNITY_SAMPLE_TEXCUBE_LOD('cubemap', 'sample coordinate', 'map-map level')
half3 skyColor = DecodeHDR (skyData, unity_SpecCube0_HDR); // This is done because the cubemap is stored HDR
return half4(skyColor, 1.0);
}The cube-map has Tri-linear mapping applied on it which allows smooth transitions between LOD mip-map levels.
Here we are taking the mip-map level as the roughness value.
Higher mip-map levels correspond to a higher roughness of the material.
Here is the entire shader code:
1Shader "BitshiftProgrammer/ReflectionProbeAccess"
2{
3 Properties
4 {
5 _Roughness("Roughness", Range(0.0, 10.0)) = 0.0
6 }
7
8 SubShader
9 {
10 Pass
11 {
12 CGPROGRAM
13 #pragma vertex vert
14 #pragma fragment frag
15 #include "UnityCG.cginc"
16
17 float _Roughness;
18
19 struct appdata
20 {
21 float4 vertex : POSITION;
22 float3 normal : NORMAL;
23 };
24
25 struct v2f
26 {
27 float3 worldPos : TEXCOORD0;
28 float3 worldNormal : TEXCOORD1;
29 float4 pos : SV_POSITION;
30 };
31
32 v2f vert (appdata v)
33 {
34 v2f o;
35 o.pos = UnityObjectToClipPos(v.vertex);
36 o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
37 o.worldNormal = UnityObjectToWorldNormal(v.normal);
38 return o;
39 }
40
41 fixed4 frag (v2f i) : SV_Target
42 {
43 half3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos)); //Direction of ray from the camera towards the object surface
44 half3 reflection = reflect(-worldViewDir, i.worldNormal); // Direction of ray after hitting the surface of object
45 /*If Roughness feature is not needed : UNITY_SAMPLE_TEXCUBE(unity_SpecCube0, reflection) can be used instead. It chooses the correct LOD value based on camera distance*/
46 half4 skyData = UNITY_SAMPLE_TEXCUBE_LOD(unity_SpecCube0, reflection, _Roughness);
47 half3 skyColor = DecodeHDR (skyData, unity_SpecCube0_HDR); // This is done becasue the cubemap is stored HDR
48 return half4(skyColor, 1.0);
49 }
50 ENDCG
51 }
52 }
53}