Screen Space Multi-Colored Fog - Unity Shader

This is how the shader will end up looking :

This shader is completely an image effect hence the title - 'Screen Space'. This method allows a great deal of control on how the fog will be rendered. The main concept explored here is the use of the 'Depth Texture' which is basically the value of the distance of a pixel from the camera.

The concept of a 'Depth Texture' is also needed to implement effects like SSAO, Soft Particles, Translucency and many more.
Here is the color ramp used :

So let's start by looking at the properties :

Properties
{
 _MainTex ("Texture", 2D) = "white" {}
 _ColorLookUp("Fog Colour Look Up", 2D) = "white"{}
 _FogSpread("Fog Spread", Float) = 10.0
}

As we except from an image effect shader there will always have a _MainTex input which the what the camera sees.
Additionally we have two more properties declared :

1. _ColorLookUp which is a texture that we provide.
2. _FogSpread which a float which is used to manipulate how the fog looks (will go into detail later)

Now we will go through how they were declared in the CG PROGRAM.

/*1*/sampler2D _MainTex;
/*2*/sampler2D _CameraDepthTexture;
/*3*/sampler1D _ColorLookUp;
/*4*/half _FogSpread;
/*5*/#define IF(a, b, c) lerp(b, c, step((fixed) (a), 0));

1. We declared _MainTex as sampler2D as usual
2. Declaring the use of the depth texture of the camera with _CameraDepthTexture ( Unity internal sampler )
3. The color look up texture that we will provide to provide color to the fog, It is only 1D a  texture. An image that is 1 pixel in height and having width of 1 or more pixels is a 1D texture.
4. Declare _FogSpread as a half ( less precision than float but better for optimization )
5. Creating a macro called IF, This statement will be replaced with what is following it. Here IF takes in 3 parameters :- a, b & c. Those parameters will be placed according to where those show up in the statement. The parameter a will be replaced by whatever was passed to IF as the first parameter and so on.

It's time for the juicy fragment shader that does all the heavy lifting:

fixed4 frag (v2f i) : SV_Target
{
 /*1*/fixed3 col = tex2D(_MainTex, i.uv);
 /*2*/float zsample = SAMPLE_DEPTH_TEXTURE(_CameraDepthTexture, i.uv);
 /*3*/float depth = Linear01Depth(zsample);
 /*4*/depth = clamp(depth * _FogSpread, 0, 1) * IF(depth < 1.0, 1, 0);
 /*5*/col *= tex1D(_ColorLookUp, depth);
 return fixed4(col,1.0);
}

Let's break it down:

1. Assigning the value of the _MainTex ( view from camera ) to a variable called col.
2. Now we sample the depth information and assign that value to a float called zsample.
3. We now normalize the depth value so that the depth info will be restricted between 0 and 1. Closer distance will have value of 0 and farther away things tend towards 1. This is platform dependent, so sometimes depth value will be inverse. You just have to subtract 1 with the normalized depth value if that is the case.
4. Here we multiply the depth value with our _FogSpread value. Larger _FogSpread values brings the end value of the fog colour much closer to the camera. So you can tweak this value to see what suits your scene. We are also checking if the depth value is less than 1.0 and if so the fog gets rendered as usual but if depth >= 1.0 then we return 0 so the entire depth value becomes 0, Thereby preventing the fog from being rendered. We have this in place to allow the skybox to be unaffected by the fog, If we remove this statement the skybox will be affected by the fog as well.
5. We just multiply the depth color with our original pixel color from our camera.

Let's move on to making the C# file that goes along with this.

1using UnityEngine;
2[ExecuteInEditMode, ImageEffectAllowedInSceneView, RequireComponent(typeof(Camera))]
3public class ScreenSpaceColouredFog: MonoBehaviour
4{
5    public Material mat;
6    private void OnRenderImage(RenderTexture src, RenderTexture dest)
7    {
8        Graphics.Blit(src, dest, mat);
9    }
10}

Here is the entire shader:

1Shader "BitshiftProductions/ColouredFog"
2{
3	Properties
4	{
5		_MainTex ("Texture", 2D) = "white" {}
6		_ColorLookUp("Fog Colour Look Up", 2D) = "white"{}
7		_FogSpread("Fog Spread", Float) = 10.0
8	}
9	SubShader
10	{
11		Cull Off ZWrite Off ZTest Always
12		Pass
13		{
14			CGPROGRAM
15			#pragma vertex vert
16			#pragma fragment frag
17			#include "UnityCG.cginc"
18
19			struct appdata
20			{
21				float4 vertex : POSITION;
22				float2 uv : TEXCOORD0;
23			};
24
25			struct v2f
26			{
27				float2 uv : TEXCOORD0;
28				float4 vertex : SV_POSITION;
29				float4 scrPos : TEXCOORD1;
30			};
31
32			v2f vert (appdata v)
33			{
34				v2f o;
35				o.vertex = UnityObjectToClipPos(v.vertex);
36				o.scrPos = ComputeScreenPos(o.vertex);
37				o.uv = v.uv;
38				return o;
39			}
40			
41			sampler2D _MainTex;
42			sampler2D _CameraDepthTexture;
43			sampler1D _ColorLookUp;
44			half _FogSpread;
45
46			#define IF(a, b, c) lerp(b, c, step((fixed) (a), 0));
47
48			fixed4 frag (v2f i) : SV_Target
49			{
50				fixed3 col = tex2D(_MainTex, i.uv);
51				float zsample = SAMPLE_DEPTH_TEXTURE(_CameraDepthTexture, i.uv);
52				float depth = Linear01Depth(zsample);
53				depth = clamp(depth * _FogSpread, 0, 1) * IF(depth < 1.0, 1, 0);
54				col *= tex1D(_ColorLookUp, depth);
55				return fixed4(col,1.0);
56			}
57			ENDCG
58		}
59	}
60}